Delphi RTTI 解析

页面导航:首页 > 软件编程 > Delphi > Delphi RTTI 解析

Delphi RTTI 解析

来源: 作者: 时间:2016-01-18 15:41 【

Delphi 的RTTI机制浅探目 录===============================================================================⊙ DFM 文件与持续机制(persistent)⊙ ReadComponentResFile / WriteComponentResFile 函...

Delphi 的RTTI机制浅探

目 录
===============================================================================
⊙ DFM 文件与持续机制(persistent)
⊙ ReadComponentResFile / WriteComponentResFile 函数
⊙ Delphi 持续机制框架简述
⊙ 一个 TForm 对象的创建过程
⊙ TStream Class 和 TStream.ReadComponent 方法
⊙ TReader Class 和 TReader.ReadRootComponent 方法
⊙ TReader.ReadPrefix 方法
⊙ TComponent.ReadState 虚方法
⊙ TReader.ReadData 方法
⊙ TReader.ReadDataInner 方法
⊙ TReader.ReadProperty 方法
⊙ TPersistent.DefineProperties 虚方法
⊙ TReader.ReadComponent 方法
⊙ TReader.ReadValue / TReader.NextValue 系列方法
⊙ TReader.ReadStr 方法
⊙ TReader.ReadInteger / ReadString / ReadBoolean 系列方法
⊙ TReader.Read 方法
⊙ ObjectBinaryToText / ObjectTextToBinary 函数
===============================================================================


本文排版格式为:
    正文由窗口自动换行;所有代码以 80 字符为边界;中英文字符以空格符分隔。

(作者保留对本文的所有权利,未经作者同意请勿在在任何公共媒体转载。)


正 文
===============================================================================
⊙ DFM 文件与持续机制(persistent)
===============================================================================
我们在使用 Delphi 的 IDE 进行快速开发的时候,可以方便地从元件面板上拖放元件(component)至表单,完成表单的界面和事件设计。Delphi 将这些界面的设计期信息保存在表单相应的 DFM 文件中,方便程序员随时读取和修改。

DFM 文件根据元件在表单上的嵌套层次存放元件属性,以下是一个 DFM 文件的示例:

  object Form1: TForm1
    ...
    Left = 192
    Top = 107
    Width = 544
    Caption = 'Form1'
    object Button1: TButton
      Left = 24
      Top = 16
      Caption = 'Button1'
      onClick = Button1Click
    end
    ...
  end

应用程序编译之后,DFM 文件的信息被二进制化了,这些二进制信息存储在应用程序的资源(resource)段中。每个表单(也就是 class)及表单上的元件在资源段中存储为与表单同名的资源,可以使用 FindResource API 获得。应用程序在运行期创建表单实例的时候,会从资源段中读取表单的属性,还原设计期的设置。这种将类型信息保存在文件中,并且可以在运行期恢复类型的操作,在本文中被称之为持续(persistent)机制。持续机制是 Delphi 成为 RAD 工具的原因之一。

持续机制和 RTTI 是紧密结合的,但本文不讨论 RTTI(关于 RTTI 可参考我前几天写的两篇笔记),只讨论实现持续机制的总体框架及相关类(class)。这些类包括 TStream、TFiler、TReader、TWriter、TParser、TPersisetent、TComponent、TCustomForm 等。

===============================================================================
⊙ ReadComponentResFile / WriteComponentResFile 函数
===============================================================================
让我们从一个比较直观的例子开始。

Classes.pas 中定义了两个函数 ReadComponentResFile 和 WriteComponentResFile,它们的功能是“把元件的属性信息保存到文件”和“从文件中恢复元件属性信息”。

先做个试验。新建一个项目,在 Form1 上放置两个 Button 和一个 Memo。Button 的 Click 事件代码如下。按 F9 运行该项目,先在 Memo1 中输入一些字符,然后按下 Button1,再按下 Button2,你会看一个新建的 Form。它的属性几乎和 Form1 一样,甚至连 Memo1 中的字符都保存下来了,唯一的不同只是它的 Name 属性变成了“Form1_1”。你可以查看 FORM1.RES 文件的内容看看 Delphi 是如何存储元件信息的。

  procedure TForm1.Button1Click(Sender: TObject);
  begin
    WriteComponentResFile('C:\FORM1.RES', Form1);
  end;
 
  procedure TForm1.Button2Click(Sender: TObject);
  var
    NewForm: TForm1;
  begin
    NewForm := TForm1.CreateNew(Application);
    ReadComponentResFile('C:\FORM1.RES', NewForm);
    NewForm.Left := NewForm.Left + 100;
  end;

WriteComponentResFile 函数的代码如下,它只是调用 Stream 对象的 WriteComponentRes 方法将对象属性保存到资源文件中的:

  procedure WriteComponentResFile(const FileName: string; Instance: TComponent);
  begin
    Stream := TFileStream.Create(FileName, fmCreate);
    Stream.WriteComponentRes(Instance.ClassName, Instance);
    Stream.Free;
  end;

ReadComponentResFile 函数也是调用 Stream 的方法实现从文件中读取对属信息:

  function ReadComponentResFile(const FileName: string; Instance: TComponent):
    TComponent;
  begin
    Stream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite);
    Result := Stream.ReadComponentRes(Instance);
    Stream.Free;
  end;

ReadComponentResFile 函数可以通过 Instance 参数传入对象句柄,也可以通过返回值获得对象句柄。Instance 参数只能是已实例化的对象或 nil。如果是 nil,那么 ReadComponentResFile 会自动根据文件信息创建对象实例,但必须使用 RegisterClass 函数注册将要被载入的类,否则会触发异常。

有个类似的函数 ReadComponentRes,它从应用程序的资源段中恢复对象的属性信息。它的 ResName 参数就是表单类的名称:

  function ReadComponentRes(const ResName: string; Instance: TComponent):
    TComponent;

===============================================================================
⊙ Delphi 持续机制框架简述
===============================================================================
持续机制的实现必须由 IDE、编译器、表单类、元件类和辅助类合作完成。

这里的表单类不是指一般所指的 TForm class,在 Delphi 的帮助文件中,称之为“root class”。root class 是指能在设计期被 Form Designer 作为最上层编辑表单的类(如 TCustomForm、TFrame、TDataModule 等)。Delphi 在设计期将元件的 published 属性的值保存在 .DFM 文件中,也只有 published 的属性才能被 Object Insepector 设置赋值。

Form Designer 设计的 root class 对象在编译时,Delphi 将对象的属性以及其所包含的元件的属性保存在应用程序的资源段(RT_RCDATA)中。

辅助类包括 TStream、TReader、TWriter、TParser 等。这些类起着中间层的作用,用于存储和读取对象属性的信息。虽然我称它们为辅助类,但是保存和恢复对象信息的实际操作是由它们完成的。

===============================================================================
⊙ 一个 TForm 对象的创建过程
===============================================================================
下面是一个典型的表单 Form1 的创建过程,缩进代表调用关系(Form1.ReadState 例外,防止缩进太多),带“?”的函数表示我尚未仔细考察的部分,带“*”表示元件编写者需要注意的函数。

Application.CreateForm(TForm1, Form1);
  |-Form1.NewInstance;
  |-Form1.Create(Application);
    |-Form1.CreateNew(Application);
    |-InitInheritedComponent(Form1, TForm);
      |-InternalReadComponentRes(Form1.ClassName, Form1ResHInst, Form1);
        |-TResourceStream.Create(Form1ResHInst, Form1.ClassName, RT_RCDATA);
        |-TResourceStream.ReadComponent(Form1);
          |-TReader.Create(ResourceStream, 4096);
          |-TReader.ReadRootComponent(Form1);
            |-TReader.ReadSignature;
           *|-TReader.ReadPrefix(Flags, ChildPos);
            |-IF Form1 = nil THEN Form1 := FindClass(ReadStr).Create;
            |-Include(Form1.FComponentState, csLoading);
            |-Include(Form1.FComponentState, csReading);
            |-Form1.Name := FindUniqueName(ReadStr);
           ?|-FFinder := TClassFinder.Create;
           *|-Form1.ReadState(Reader);
              |-TCustomForm.ReadState(Reader);
                { DisableAlign; }
              |-TWinControl.ReadState(Reader);
                { DisableAlign; }
             *|-TControl.ReadState(Reader);
                { Include(FControlState, csReadingState); }
                { Parent := TWinControl(Reader.Parent);   }
             *|-TComponent.ReadState(Reader);
                |-Reader.ReadData(Form1);
                  |-Reader.ReadDataInner(Form1);
                    |-WHILE NOT EndOfList DO Reader.ReadProperty(Form1);
                      |-IF PropInfo <> nil THEN ReadPropValue(Form1, PropInfo);
                     *|-ELSE Form1.DefineProperties(Reader);
                    |-WHILE NOT EndOfList DO ReadComponent(nil);
                      |-ReadPrefix(Flags, Position);
                      |-IF ffInherited THEN FindExistingComponent
                      |-ELSE CreateComponent;
                     *|-SubComponent.ReadState(Reader); (Like Form1.ReadState)
                 ?|-DoFixupReferences;

过程简述:

TCustomForm.Create 函数中先调用 CreateNew 设置缺省的表单属性,然后调用Classes.InitInheritedComponent 函数。

InitInheritedComponent 用于初始化一个 root class 对象。该函数的功能就是从应用程序的资源中恢复设计期的表单信息。InitInheritedComponent 的声明如下:

  { Classes.pas }
  function InitInheritedComponent(Instance: TComponent;
    RootAncestor: TClass): Boolean;

InitInheritedComponent 传入两个参数:Instance 参数代表将要从资源段中恢复信息的对象,RootAncestor 表示该对象的祖先类。如果从资源中恢复信息成功,则返回 True,否则返回 False。InitInheritedComponent 通常只在 root class 的构造函数中调用。

  constructor TCustomForm.Create(AOwner: TComponent);
  begin
    ...
    CreateNew(AOwner);                              // 初始化缺省的 Form 属性
    Include(FFormState, fsCreating);                // 标记为 Creating 状态
    if not InitInheritedComponent(Self, TForm) then // 从资源中恢复 Form 信息
      raise EResNotFound.CreateFmt(SResNotFound, [ClassName]);
    ...
    Exclude(FFormState, fsCreating);                // 取消 Creating 状态
  end;

InitInheritedComponent 调用自身内置的函数:InitComponent(Instance.ClassType)。InitComponent 先判断 Instance.ClassType 是否是 TComponent 或 RootAncestor,如果是则返回 False 并退出,否则调用 InternalReadComponentRes。

* InitComponent 递归调用自己检查类信息。没看懂为什么要这样设计,如果有谁看懂了请告诉我。

  function InitComponent(ClassType: TClass): Boolean;
  begin
    Result := False;
    if (ClassType = TComponent) or (ClassType = RootAncestor) then Exit;
    Result := InitComponent(ClassType.ClassParent);
    Result := InternalReadComponentRes(ClassType.ClassName,
      FindResourceHInstance(FindClassHInstance(ClassType)), Instance) or Result;
  end;

InternalReadComponentRes 使用 Instance.ClassName 作为 ResourceName,调用 FindResourceHInstance 找到 class 资源所在模块的 HInst 句柄(因为 class 可能是在动态链接库中),并通过引用方式传递 Instance 对象(* 好像没有必要使用引用方式,InitInheritedComponent 也没有使用引用方式):

  { Classes.pas }
  function InternalReadComponentRes(const ResName: string; HInst: THandle;
    var Instance: TComponent): Boolean;

InternalReadComponentRes 先检查 class 资源是否存在,如果存在则创建一个 TResourceStream 对象(TResourceStream 的 Create 构造函数把 class 信息的资源内存地址和大小记录在成员字段中),然后使用 TResourceStream.ReadComponent 方法从资源中读取 Instance 的信息。TResourceStream 并没有定义 ReadComponent 方法,而是使用祖先类 TStream 的方法。TStream.ReadComponent 创建一个 TReader 对象,然后使用自己的对象地址(Self)作为参数,调用 TReader.ReadRootComponent 读取 Instance 对象的内容。

  { TReader }
  function ReadRootComponent(Root: TComponent): TComponent;

ReadRootComponent 先调用 TReader.ReadSignature。ReadSignature 从 stream 中读取 4 字节的内容,如果读出来的内容不是 'TPF0',则触发异常(SInvalidImage),表示该 stream 的内容是错误的。然后 ReadRootComponent 调用 ReadPrefix 读取元件的状态信息。

如果 Root 参数是 nil,也就是说 Root 对象还没被创建,则直接从流中读取 Root 的类名,再使用 FindClass 函数找到该类在内存中的地址,并调用该类的构造函数创建 Root 的实例。

接下来 ReadRootComponent 调用 Root 的 ReadState 虚函数从流中读取 Root 对象的属性。TComponent.ReadState 只有一行代码:Reader.ReadData(Self);。

ReadData 调用 ReadDataInner 读取 root 元件及 root 的子元件的属性信息。

ReadDataInner 先循环调用 ReadProperty 从流中读取 root 元件的属性,直到遇到 EndOfList 标志(vaNull)。ReadProperty 使用 RTTI 函数,将从流中读出的数据设置为对象的属性。ReadProperty 中还调用了 Instance.DefineProperties,用于实现自定义的属性存储。ReadDataInner 然后循环调用 ReadComponent(nil) 读取子元件的信息。

ReadComponent 的执行过程与 ReadRootComponent 的过程很相似,它根据流中的信息使用 FindComponentClass 找到元件类在内存中的地址,然后调用该元件类的构造函数创建对象,接下来调用新建对象的 ReadState -> TReader.ReadData -> ReadDataInner -> TReader.ReadProperty,重复 ReadRootComponent 的过程。

TReader.ReadComponent 和 TComponent.ReadState 形成递归调用过程,把表单上嵌套的元件创建出来。

最后 InitInheritedComponent 函数返回,一个 root class 对象从资源中实例化的过程完成。

===============================================================================
⊙ TStream Class 和 TStream.ReadComponent 方法
===============================================================================
TStream 在对象持续机制扮演的角色是提供一种存储媒介,由 TFiler 对象使用。TStream 是一个虚类,它定义了数据的“流式”读写方法。它的继承类 TFileStream、TMemoryStream、TResourceStream 等实现对不同媒体的读写。对象的 persistent 信息可以存储在任何 TStream 类中,也可以从任何 TStream 中获得。由于 Delphi 缺省的对象信息存储在应用程序的资源段中,因此,可以从程序的资源段中读取数据的 TResourceStream 类就显得更加重要。

TStream 定义两个读写缓冲的方法:ReadBuffer 和 WriteBuffer。这两个方法封装了 TStream.Read 和 TStream.Write 纯虚方法(必须被后继类重载)。

  { TStream }
  procedure ReadBuffer(var Buffer; Count: Longint);
  procedure WriteBuffer(const Buffer; Count: Longint);

可以看到这两个方法的 Buffer 参数都是无类型的,也就是使用引用的方式传入的,所以不管是使用单个字符或自定义的结构都是正确的(当然,不能使用常量)。Count 指示要读或写入的 Buffer 的大小(Bytes)。

TStream 还定义了两个元件信息的读写方法:ReadComponent 和 WriteComponent。由于 WriteComponent 通常是由 Delphi 的 IDE/编译器调用的,很难跟踪它的执行过程,所以我们以后主要考察 ReadComponent 方法。我们可以很容易想像这两个方法互为逆过程,理解了其中一个也就能知道另一个所做的工作。

  { TStream }
  function ReadComponent(Instance: TComponent): TComponent;
  procedure WriteComponent(Instance: TComponent);

TStream.ReadComponent 创建了一个 TReader 对象,将自己的对象地址作为参数传递给 Reader,并调用 Reader.ReadRootComponent 创建对象实例。

  function TStream.ReadComponent(Instance: TComponent): TComponent;
  var
    Reader: TReader;
  begin
    Reader := TReader.Create(Self, 4096);        // 4096 是缓冲区大小
    Result := Reader.ReadRootComponent(Instance);
    Reader.Free;
  end;

TStream 把自己的对象句柄交给 TReader 之后,就成了 TReader 读取对象属性资料的来源。此后 TStream 对象只由 TReader 来掌控,自己不再主动进行其它工作。

===============================================================================
⊙ TReader Class 和 TReader.ReadRootComponent 方法
===============================================================================
TReader 和 TWriter 都是从 TFiler 继承下来的类。TFiler 是个纯虚类,它的构造函数被 TReader 和 TWrite 共享。TFiler.Create 先把 Stream 参数保存在 FStream 字段中,然后生成一个自己的缓冲区:

  constructor TFiler.Create(Stream: TStream; BufSize: Integer);
  begin
    FStream := Stream;          // 保存 stream 对象
    GetMem(FBuffer, BufSize);   // 创建自己的缓冲区,加速数据访问
    FBufSize := BufSize;        // 设置缓冲区大小
  end;

上面说到 TStream.ReadComponent 在创建 TReader 对象之后,立即调用 TReader.ReadRootComponent 方法。TReader.ReadRootComponent 方法的功能是从 stream 中读取 root class 对象的属性。并返回该对象的指针。

  { TReader }
  function ReadRootComponent(Root: TComponent): TComponent;

ReadRootComponent 先调用 TReader.ReadSignature。

TReader.ReadSignature 方法从 stream 中读取 4 字节的内容,如果读出来的内容不是 'TPF0',则触发异常(SInvalidImage),表示该 stream 的内容是错误的。'TPF0' 就是 root class 对象的标记。

然后 ReadRootComponent 调用 ReadPrefix 读取元件的继承信息。

如果 Root 参数是 nil,也就是说 Root 对象还没被创建,则直接从流中读取 Root 的类名,再使用 FindClass 函数找到该类在内存中的地址,并调用该类的构造函数创建 Root 的实例。如果 Root 实例已存在,则调用内嵌的 FindUniquName 函数检查 Root.Name 是否与已有的实例重复,如有重复则在 Root.Name 后加上序号使其唯一。

接下来 ReadRootComponent 调用 Root 的 ReadState 虚方法从流中读取 Root 对象的属性。

===============================================================================
⊙ TReader.ReadPrefix 方法
===============================================================================
ReadPrefix 方法用于读取元件的状态信息,这些信息是由 Writer 在写入元件属性之前写入的。

  { TReader }
  procedure ReadPrefix(var Flags: TFilerFlags; var AChildPos: Integer); virtual;

Flags 参数是以引用方式传递的,用于设置元件的在表单中的状态,元件的状态在这里包含三种情况:

  ffInherited:表示元件存在于表单的父类之中
  ffChildPos :表示元件在表单中的创建次序(creation order)是重要的
  ffInline   :表示元件是最上级(top-level)的元件,比如表单或数据模块

如果元件的状态中包含 ffChildPos,ReadPrefix 还会读取元件的创建次序值,存放在 AChildPos 参数中。

===============================================================================
⊙ TComponent.ReadState 虚方法
===============================================================================
设置 ReadState 方法的主要目的是在读取属性信息的前后可以让元件进行一些处理工作。ReadState 是 Component Writer 需要注意的方法。

  { TComponent }
  procedure ReadState(Reader: TReader); virtual;

由于 ReadState 是虚函数,在 TControl、TWinControl、TCustomForm 等后续类中都被重载,进行自己需要的操作(比如 DisableAlign、UpdateControlState)。

TComponent.ReadState 只有一行代码:Reader.ReadData(Self);

注意:自己重载 ReadState 方法必须调用 inherited 。

===============================================================================
⊙ TReader.ReadData 方法
===============================================================================
上面说到 TComponent.ReadState 又回头调用 TReader.ReadData 方法。它的主要代码如下:

  { TReader }
  procedure TReader.ReadData(Instance: TComponent);
  begin
    ...
    ReadDataInner(Instance);
    DoFixupReferences;
    ...
  end;

TReader.ReadData 基本上是个包装函数,它调用 TReader.ReadDataInner 读取 root 对象及 root 所包含的元件的属性信息。

===============================================================================
⊙ TReader.ReadDataInner 方法
===============================================================================
ReadDataInner 负责读取元件的属性和子元件的属性,它的主要代码如下:

  procedure TReader.ReadDataInner(Instance: TComponent);
    begin
    ...
    while not EndOfList do ReadProperty(Instance);
    ...
    while not EndOfList do ReadComponent(nil);
    ...
  end;

ReadDataInner 先循环调用 ReadProperty 从流中读取对象的属性,直到遇到 EndOfList 标志(vaNull)。再循环调用 ReadComponent(nil) 读取子元件的信息。这两个方法都是 TReader 的重要方法,后面分两节讨论。ReadDataInner 在ReadProperty 调用之后还设置了元件的 Parent 和 Owner 关系。

===============================================================================
⊙ TReader.ReadProperty 方法
===============================================================================
ReadProperty 使用 RTTI 函数将从流中读出的数据设置为对象的属性。它先解析从流中读出的属性名称,然后判断该属性是否有 RTTI 信息,如果有则调用 TReader.ReadPropValue 方法从流中读取属性值;如果该属性没有 RTTI 信息,说明该属性不属于 published 段,而是由元件自己写入的,因此调用 TPersistent.DefineProperties 读取自定义的元件信息。ReadProperty 的关键代码:

  procedure TReader.ReadProperty(AInstance: TPersistent);
  begin
    ...
    PropInfo := GetPropInfo(Instance.ClassInfo, FPropName);
    if PropInfo <> nil then                             // 检查属性 RTTI 信息
      ReadPropValue(Instance, PropInfo)                 // 从流中读取属性
    else begin
      Instance.DefineProperties(Self);                  // 调用自定义存储过程
      if FPropName <> '' then PropertyError(FPropName); // 注意这里
    end;
    ...
  end;

ReadPropValue 方法基本上是使用 SetOrdProp、SetFloatProp、SetStrProp、GetEnumValue 等 RTTI 函数设置元件的属性值,它的代码冗长而简单,不再单独列出。下面介绍比较重要的 DefineProperties 函数。

===============================================================================
⊙ TPersistent.DefineProperties 虚方法
===============================================================================
DefineProperties 虚方法用于元件设计者自定义非 published 属性的存储和读取方法。 TPersistent 定义的该方法是个空方法,到 TComponent 之后被重载。

   procedure TPersistent.DefineProperties(Filer: TFiler); virtual;

下面以 TComponent 为例说明该方法的用法:

  procedure TComponent.DefineProperties(Filer: TFiler);
  var
    Ancestor: TComponent;
    Info: Longint;
  begin
    Info := 0;
    Ancestor := TComponent(Filer.Ancestor);
    if Ancestor <> nil then Info := Ancestor.FDesignInfo;
    Filer.DefineProperty('Left', ReadLeft, WriteLeft,
      LongRec(FDesignInfo).Lo <> LongRec(Info).Lo);
    Filer.DefineProperty('Top', ReadTop, WriteTop,
      LongRec(FDesignInfo).Hi <> LongRec(Info).Hi);
  end;

DefineProperties 调用 Filer.DefineProperty 或 DefineBinaryProperty 方法读写流中属性值。

TReader.DefineProperty 方法检查传入的属性名称是否与当前流中读到的属性名称相同,如果相同,则调用传入的 ReadData 方法读取数据,并设置 FPropName 为空,用以通知 ReadProperty 已经完成读属性值的工作,否则将会触发异常。

  procedure TReader.DefineProperty(const Name: string;
    ReadData: TReaderProc; WriteData: TWriterProc; HasData: Boolean);
  begin
    if SameText(Name, FPropName) and Assigned(ReadData) then
    begin
      ReadData(Self);
      FPropName := '';
    end;
  end;

TWriter.DefineProperty 根据 HasData 参数决定是否需要写属性值。

  procedure TWriter.DefineProperty(const Name: string;
    ReadData: TReaderProc; WriteData: TWriterProc; HasData: Boolean);
  begin
    if HasData and Assigned(WriteData) then
    begin
      WritePropName(Name);
      WriteData(Self);
    end;
  end;

如果 Filer.Ancestor 不是 nil,表示当前正在读取的元件继承自表单父类中的元件,元件设计者可以根据 Ancestor 判断是否需要写属性至流中。例如:当前元件的属性值与原表单类中的元件属性值相同的时候,可以不写入(通常是这样设计)。

ReadData、WriteData 参数是从 Filer 对象中读写数据的方法地址,它们的类型是:

  TReaderProc = procedure(Reader: TReader) of object;
  TWriterProc = procedure(Writer: TWriter) of object;

比如:

  procedure TComponent.ReadLeft(Reader: TReader);
  begin
    LongRec(FDesignInfo).Lo := Reader.ReadInteger;
  end;

  procedure TComponent.WriteLeft(Writer: TWriter);
  begin
    Writer.WriteInteger(LongRec(FDesignInfo).Lo);
  end;
 
对于二进制格式的属性值,可以使用 TFiler.DefineBinaryProperty 方法读写:

  procedure DefineBinaryProperty(const Name: string;
    ReadData, WriteData: TStreamProc; HasData: Boolean); override;

  TStreamProc = procedure(Stream: TStream) of object;

Stream 参数是从流中读出的二进制数据或要写入二进制数据的流对象句柄。

注意:自己定义属性的读写方法时要记得调用 inherited DefineProperties(Filer),否则祖先类的自定义属性读写操作不会进行。TControl 是个例外,因为它已经定义了 published Left 和 Top 属性。

Tags:

文章评论

最 近 更 新
热 点 排 行
Js与CSS工具
代码转换工具

<