创建透明窗体

页面导航:首页 > 软件编程 > Delphi > 创建透明窗体

创建透明窗体

来源: 作者: 时间:2016-02-05 11:47 【

也许你曾经看见过这样的一些窗体,它的一部分是透明的。那么我们在Delphi中应该怎么实现这种效果呢?下面的将说到如何实现这种效果: 一种方法是为你的窗体添加 WS_EX_TRANSPARENT&n

 

 

  也许你曾经看见过这样的一些窗体,它的一部分是透明的。那么我们在Delphi中应该怎么实现这种效果呢?下面的将说到如何实现这种效果:

  一种方法是为你的窗体添加 WS_EX_TRANSPARENT 样式。虽然它可以动作起来,但是它还不能完全实现我们想要的效果,而且,微软也建议只为那些运行期比较短的样式窗体使用 WS_EX_TRANSPARENT 样式。

  第二种方法就是应用WIN2000所支持的层次化窗体特性。不过这将使你的应用程序只局限在WIN2000下使用。

  本文所采用的是第三种方法。你可以使用 SetWindowRgn API函数精确的指定你所需要窗体显示的部分。这其中最困难的就是要创建你所要显示的那部分窗体的区域。解决问题的办法就是遍历窗体上所有可视的控件,然后创建包含所有这些小区域的一个巨大的区域。下面是具体的实现:

procedure TForm1.SetRegions;
var
  I: Integer;
  RgnAll, RgnCtrl: HRGN;
begin
  RgnAll := 0;
  for I := 0 to ControlCount - 1 do
  begin
    with Controls[I] do
    begin
      if Visible then
      begin
        // 为所有的可视控件创建一个区域
        RgnCtrl := CreateRectRgn(Left, Top, Left + Width, Top + Height);
        // 组合上面创建的所有区域
        if (RgnCtrl <> 0) and (RgnAll <> 0) then
        begin
          CombineRgn(RgnAll, RgnAll, RgnCtrl, RGN_OR);
          DeleteObject(RgnCtrl);
        end
        else
          RgnAll := RgnCtrl; // 这是第一个创建的区域
      end;
    end;
  end;
  // Now, set the RgnAll as what we see for the Window
  if RgnAll <> 0 then
  begin
    (*
      下面是SetWindowRgn在帮助文件中的注释:
     ”当调用SetWindowRgn成功后,操作将拥有区域句柄hRgn所指定的区域。并且操作系统没有为这个区域考贝副本。因此,你不应再用这个区域句柄调用其它的函数。特别是不要关闭这个句柄。”
   因此不要在使用SetWindowRgn后对RgnAll调用DeleteObject(感谢Richard Albury指出这点)该文的以前版本就范了以上错误。     
    *)
    SetWindowRgn(Handle, RgnAll, True);
  end;
end;

  注意,我在使用完这个区域后应该怎样调用DeleteObject呢。如果不调用,将导致Windows资源的泄漏。我使用API CreateRectRgn,如果你有不同的形状也可以使用CreatePolygonRgn。

  你会碰到的一个问题是如何处理窗体中移动的控件。如果你作用程序移动控件(比如:在OnMouseMove事件当中),那么控件后面的区域将会露出来。同样,控件在移动后也许不能正确的重画。这有一个简单的方法就是重新调用etRegions函数更新窗体中可见的区域,并且调用控件的Repaint方法使控强制性的重画。如下:
procedure TForm1.GenericMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
  // 如果控件没有移动,则立刻退出。
  if (X - LastX = 0) and (Y - LastY = 0) then Exit;
  // 移动控件
  with (Sender as TControl) do
  begin
    Left := Left + (X - LastX);
    Top := Top + (Y - LastY);
  end;
  SetRegions;
  (Sender as TControl).Repaint;
end;

  现在你将能为你的窗体添加透明的效果了。

Tags:

相关文章

    文章评论

    最 近 更 新
    热 点 排 行
    Js与CSS工具
    代码转换工具
    
    <