使用LotusScript排序

页面导航:首页 > 软件编程 > vb.net > 使用LotusScript排序

使用LotusScript排序

来源: 作者: 时间:2016-01-18 16:54 【

排序是计算机编程中最常见的任务之一,排序算法也是最基本和常用的算法。存在许多种排序算法,它们的效率和复杂性各不相同。在LotusNotes中,[email protected],对List排序。
排序是计算机中最常见的任务之一,排序算法也是最基本和常用的算法。存在许多种排序算法,它们的效率和复杂性各不相同。在LotusNotes中,[email protected][email protected]数据结构,也就没有提供针对它们的排序功能。另外,使用LotusScript开发时,主要的数据对象是NotesDocument,而它们的排序都已经在视图里完成了,所以需要排序的情况并不多。但是有时候,我们也会遇到排序的需求,比如针对列表字段里的多值或是没有存在于文档中的数据。这时就需要我们在LotusScript里实现排序算法。这并不是特别困难的事,不过如果你想省事(像我一样),也可以使用现成的代码,比如下面的这几个用于排序的函数就来自于LotusNotes自带的模版:
[vb] 
Public Function QuickSort(sArray As Variant) As Variant  
    Dim sA() As String      
    Dim j As Long  
    Dim bottom As Long  
    Dim top As Long  
    Dim vA As Variant  
      
    bottom = LBound ( sArray )  
    top = UBound ( sArray )  
    ReDim sA( bottom To top ) As String       
    For j = bottom To top  
        sA ( j ) = sArray ( j )  
    Next  
     ' DoQS does a QuickSort if the Sublist is longer than 10 elements  
     ' Thus, when DoQS finishes, all elements are within 10 spots of their correct location.  
     ' For lists that are close to being in order, an Insertion Sort is much faster than a QuickSort, so we  
     ' run through the whole thing once doing an Insertion Sort to finish tidying up the order.  
    Call DoQS( sA, bottom, top )  
    Call DoInsertSort ( sA, bottom, top )  
    ReDim vA(bottom To top) As Variant  
    For j = bottom To top  
        vA ( j ) = sA ( j )  
    Next      
    QuickSort = vA  
End Function  
Sub DoInsertSort ( sA() As String, ByVal bottom As Long, ByVal top As Long )      
    Dim i As Long  
    Dim x As Long  
    Dim v As String  
    Dim Found As Integer  
    For i = bottom+1 To top  
        x = i  
        v = sA (i )  
        Do While (sA(x-1) > v)  
            sA ( x ) = sA ( x-1 )  
            x = x - 1  
            If x=0 Then  
                Exit Do  
            End If  
        Loop  
        sA (x) = v  
    Next  
End Sub  
Sub DoQS( sA() As String, bottom As Long, top As Long )  
     ' Called by QuickSort  
    Dim length As Long  
    Dim i As Long  
    Dim j As Long  
    Dim Pivot As Long  
    Dim PivotValue As String  
    Dim t As String  
    Dim LastSmall As Long  
    length = top - bottom + 1  
      
     ' Only do the QuickSort if the sublist is at least 10 items long  
    If length > 10 Then  
          ' Pivot is chosen approx. halfway through sublist.  
          ' This gives us best speed if list is almost sorted already, and is no worse than any  
          ' other choice if the list is in random order.  
        Pivot = bottom + (length \ 2)     
          
          ' Move PivotValue out of the way  
        PivotValue = sA( Pivot )  
        sA ( Pivot ) = sA ( bottom )  
        sA ( bottom ) = PivotValue  
          
          ' LastSmall is the location of the last value smaller than PivotValue  
        LastSmall = bottom  
        For i = bottom + 1 To top   
            If sA ( i ) < PivotValue Then   
                LastSmall = LastSmall + 1  
                t = sA ( i )  
                sA ( i ) = sA ( LastSmall )  
                sA ( LastSmall ) = t  
            End If  
        Next  
          
          ' Move the PivotValue back  
        t = sA ( LastSmall )  
        sA ( LastSmall ) = sA ( bottom )  
        sA ( bottom ) = t  
        Pivot = LastSmall  
          
          ' Now sort each side  
        Call DoQS ( sA, bottom, Pivot - 1 )  
        Call DoQS ( sA, Pivot + 1, top )  
    End If  
      
End Sub  
只需要调用QuickSort函数,它会对参数中的数组排序然后返回。它根据数组的大小采用快速排序和插入排序两种不同的算法。
Tags:

文章评论

最 近 更 新
热 点 排 行
Js与CSS工具
代码转换工具

<