脚本宝典收集整理的这篇文章主要介绍了批处理（bat）实现全盘搜索指定文件获取其完整路径方法大全，脚本宝典觉得挺不错的，现在分享给大家，也给大家做个参考。
废话不多说，直接上代码，额，想用的话，自己保存成bat文件即可。
【方案一】for /f + dir
@echo off rem 指定待搜索的文件 set "FileName=BatHome_Batcher.txt" echo 正在搜索，请稍候... for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do ( if exist %%a:\ ( for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do ( if /i "%%~nxb" equ "%FileName%" ( echo,%%b ) ) ) )
【方案二】for /r（比 for /f + dir 效率高，但不会遍历隐藏文件）
@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
pushd %%a:\
for /r %%b in (*%FileName%) do (
if /i "%%~nxb" equ "%FileName%" (
echo,%%b
)
)
popd
)
)
【方案三】WMIC（Win2000/winxp HOME版、Winxp 精简版可能不支持）
@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in ("%FileName%") do (
set "nName=%%~na"
set "xName=%%~xa"
)
set "xName=%xName:~1%"
for /f "skip=1 delims=" %%a in ('wmic datafile where "filename='%nName%' and Extension='%xName%'" get name') do (
echo,%%a
)
【方案四】使用 Windows7 系统自带的 where 命令
@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
for /f "delims=" %%b in ('where /r %%a: "%FileName%" 2^>nul') do (
if /i "%%~nxb" equ "%FileName%" (
echo,%%b
)
)
)
)
以上是脚本宝典为你收集整理的批处理（bat）实现全盘搜索指定文件获取其完整路径方法大全全部内容，希望文章能够帮你解决批处理（bat）实现全盘搜索指定文件获取其完整路径方法大全所遇到的问题。
本图文内容来源于网友网络收集整理提供，作为学习参考使用，版权属于原作者。
如您有任何意见或建议可联系处理。小编QQ：384754419，请注明来意。